| // Dear ImGui: standalone example application for OSX + Metal. |
| // If you are new to Dear ImGui, read documentation from the docs/ folder + read the top of imgui.cpp. |
| // Read online: https://github.com/ocornut/imgui/tree/master/docs |
| |
| #import <Foundation/Foundation.h> |
| |
| #if TARGET_OS_OSX |
| #import <Cocoa/Cocoa.h> |
| #else |
| #import <UIKit/UIKit.h> |
| #endif |
| |
| #import <Metal/Metal.h> |
| #import <MetalKit/MetalKit.h> |
| |
| #include "imgui.h" |
| #include "imgui_impl_metal.h" |
| #if TARGET_OS_OSX |
| #include "imgui_impl_osx.h" |
| @interface AppViewController : NSViewController<NSWindowDelegate> |
| @end |
| #else |
| @interface AppViewController : UIViewController |
| @end |
| #endif |
| |
| @interface AppViewController () <MTKViewDelegate> |
| @property (nonatomic, readonly) MTKView *mtkView; |
| @property (nonatomic, strong) id <MTLDevice> device; |
| @property (nonatomic, strong) id <MTLCommandQueue> commandQueue; |
| @end |
| |
| //----------------------------------------------------------------------------------- |
| // AppViewController |
| //----------------------------------------------------------------------------------- |
| |
| @implementation AppViewController |
| |
| -(instancetype)initWithNibName:(nullable NSString *)nibNameOrNil bundle:(nullable NSBundle *)nibBundleOrNil |
| { |
| self = [super initWithNibName:nibNameOrNil bundle:nibBundleOrNil]; |
| |
| _device = MTLCreateSystemDefaultDevice(); |
| _commandQueue = [_device newCommandQueue]; |
| |
| if (!self.device) |
| { |
| NSLog(@"Metal is not supported"); |
| abort(); |
| } |
| |
| // Setup Dear ImGui context |
| // FIXME: This example doesn't have proper cleanup... |
| IMGUI_CHECKVERSION(); |
| ImGui::CreateContext(); |
| ImGuiIO& io = ImGui::GetIO(); (void)io; |
| io.ConfigFlags |= ImGuiConfigFlags_NavEnableKeyboard; // Enable Keyboard Controls |
| io.ConfigFlags |= ImGuiConfigFlags_NavEnableGamepad; // Enable Gamepad Controls |
| |
| // Setup Dear ImGui style |
| ImGui::StyleColorsDark(); |
| //ImGui::StyleColorsLight(); |
| |
| // Setup Renderer backend |
| ImGui_ImplMetal_Init(_device); |
| |
| // Load Fonts |
| // - If no fonts are loaded, dear imgui will use the default font. You can also load multiple fonts and use ImGui::PushFont()/PopFont() to select them. |
| // - AddFontFromFileTTF() will return the ImFont* so you can store it if you need to select the font among multiple. |
| // - If the file cannot be loaded, the function will return a nullptr. Please handle those errors in your application (e.g. use an assertion, or display an error and quit). |
| // - The fonts will be rasterized at a given size (w/ oversampling) and stored into a texture when calling ImFontAtlas::Build()/GetTexDataAsXXXX(), which ImGui_ImplXXXX_NewFrame below will call. |
| // - Use '#define IMGUI_ENABLE_FREETYPE' in your imconfig file to use Freetype for higher quality font rendering. |
| // - Read 'docs/FONTS.md' for more instructions and details. |
| // - Remember that in C/C++ if you want to include a backslash \ in a string literal you need to write a double backslash \\ ! |
| //io.Fonts->AddFontDefault(); |
| //io.Fonts->AddFontFromFileTTF("c:\\Windows\\Fonts\\segoeui.ttf", 18.0f); |
| //io.Fonts->AddFontFromFileTTF("../../misc/fonts/DroidSans.ttf", 16.0f); |
| //io.Fonts->AddFontFromFileTTF("../../misc/fonts/Roboto-Medium.ttf", 16.0f); |
| //io.Fonts->AddFontFromFileTTF("../../misc/fonts/Cousine-Regular.ttf", 15.0f); |
| //ImFont* font = io.Fonts->AddFontFromFileTTF("c:\\Windows\\Fonts\\ArialUni.ttf", 18.0f, nullptr, io.Fonts->GetGlyphRangesJapanese()); |
| //IM_ASSERT(font != nullptr); |
| |
| return self; |
| } |
| |
| -(MTKView *)mtkView |
| { |
| return (MTKView *)self.view; |
| } |
| |
| -(void)loadView |
| { |
| self.view = [[MTKView alloc] initWithFrame:CGRectMake(0, 0, 1200, 720)]; |
| } |
| |
| -(void)viewDidLoad |
| { |
| [super viewDidLoad]; |
| |
| self.mtkView.device = self.device; |
| self.mtkView.delegate = self; |
| |
| #if TARGET_OS_OSX |
| ImGui_ImplOSX_Init(self.view); |
| [NSApp activateIgnoringOtherApps:YES]; |
| #endif |
| } |
| |
| -(void)drawInMTKView:(MTKView*)view |
| { |
| ImGuiIO& io = ImGui::GetIO(); |
| io.DisplaySize.x = view.bounds.size.width; |
| io.DisplaySize.y = view.bounds.size.height; |
| |
| #if TARGET_OS_OSX |
| CGFloat framebufferScale = view.window.screen.backingScaleFactor ?: NSScreen.mainScreen.backingScaleFactor; |
| #else |
| CGFloat framebufferScale = view.window.screen.scale ?: UIScreen.mainScreen.scale; |
| #endif |
| io.DisplayFramebufferScale = ImVec2(framebufferScale, framebufferScale); |
| |
| id<MTLCommandBuffer> commandBuffer = [self.commandQueue commandBuffer]; |
| |
| MTLRenderPassDescriptor* renderPassDescriptor = view.currentRenderPassDescriptor; |
| if (renderPassDescriptor == nil) |
| { |
| [commandBuffer commit]; |
| return; |
| } |
| |
| // Start the Dear ImGui frame |
| ImGui_ImplMetal_NewFrame(renderPassDescriptor); |
| #if TARGET_OS_OSX |
| ImGui_ImplOSX_NewFrame(view); |
| #endif |
| ImGui::NewFrame(); |
| |
| // Our state (make them static = more or less global) as a convenience to keep the example terse. |
| static bool show_demo_window = true; |
| static bool show_another_window = false; |
| static ImVec4 clear_color = ImVec4(0.45f, 0.55f, 0.60f, 1.00f); |
| |
| // 1. Show the big demo window (Most of the sample code is in ImGui::ShowDemoWindow()! You can browse its code to learn more about Dear ImGui!). |
| if (show_demo_window) |
| ImGui::ShowDemoWindow(&show_demo_window); |
| |
| // 2. Show a simple window that we create ourselves. We use a Begin/End pair to create a named window. |
| { |
| static float f = 0.0f; |
| static int counter = 0; |
| |
| ImGui::Begin("Hello, world!"); // Create a window called "Hello, world!" and append into it. |
| |
| ImGui::Text("This is some useful text."); // Display some text (you can use a format strings too) |
| ImGui::Checkbox("Demo Window", &show_demo_window); // Edit bools storing our window open/close state |
| ImGui::Checkbox("Another Window", &show_another_window); |
| |
| ImGui::SliderFloat("float", &f, 0.0f, 1.0f); // Edit 1 float using a slider from 0.0f to 1.0f |
| ImGui::ColorEdit3("clear color", (float*)&clear_color); // Edit 3 floats representing a color |
| |
| if (ImGui::Button("Button")) // Buttons return true when clicked (most widgets return true when edited/activated) |
| counter++; |
| ImGui::SameLine(); |
| ImGui::Text("counter = %d", counter); |
| |
| ImGui::Text("Application average %.3f ms/frame (%.1f FPS)", 1000.0f / io.Framerate, io.Framerate); |
| ImGui::End(); |
| } |
| |
| // 3. Show another simple window. |
| if (show_another_window) |
| { |
| ImGui::Begin("Another Window", &show_another_window); // Pass a pointer to our bool variable (the window will have a closing button that will clear the bool when clicked) |
| ImGui::Text("Hello from another window!"); |
| if (ImGui::Button("Close Me")) |
| show_another_window = false; |
| ImGui::End(); |
| } |
| |
| // Rendering |
| ImGui::Render(); |
| ImDrawData* draw_data = ImGui::GetDrawData(); |
| |
| renderPassDescriptor.colorAttachments[0].clearColor = MTLClearColorMake(clear_color.x * clear_color.w, clear_color.y * clear_color.w, clear_color.z * clear_color.w, clear_color.w); |
| id <MTLRenderCommandEncoder> renderEncoder = [commandBuffer renderCommandEncoderWithDescriptor:renderPassDescriptor]; |
| [renderEncoder pushDebugGroup:@"Dear ImGui rendering"]; |
| ImGui_ImplMetal_RenderDrawData(draw_data, commandBuffer, renderEncoder); |
| [renderEncoder popDebugGroup]; |
| [renderEncoder endEncoding]; |
| |
| // Present |
| [commandBuffer presentDrawable:view.currentDrawable]; |
| [commandBuffer commit]; |
| } |
| |
| -(void)mtkView:(MTKView*)view drawableSizeWillChange:(CGSize)size |
| { |
| } |
| |
| //----------------------------------------------------------------------------------- |
| // Input processing |
| //----------------------------------------------------------------------------------- |
| |
| #if TARGET_OS_OSX |
| |
| - (void)viewWillAppear |
| { |
| [super viewWillAppear]; |
| self.view.window.delegate = self; |
| } |
| |
| - (void)windowWillClose:(NSNotification *)notification |
| { |
| ImGui_ImplMetal_Shutdown(); |
| ImGui_ImplOSX_Shutdown(); |
| ImGui::DestroyContext(); |
| } |
| |
| #else |
| |
| // This touch mapping is super cheesy/hacky. We treat any touch on the screen |
| // as if it were a depressed left mouse button, and we don't bother handling |
| // multitouch correctly at all. This causes the "cursor" to behave very erratically |
| // when there are multiple active touches. But for demo purposes, single-touch |
| // interaction actually works surprisingly well. |
| -(void)updateIOWithTouchEvent:(UIEvent *)event |
| { |
| UITouch *anyTouch = event.allTouches.anyObject; |
| CGPoint touchLocation = [anyTouch locationInView:self.view]; |
| ImGuiIO &io = ImGui::GetIO(); |
| io.AddMouseSourceEvent(ImGuiMouseSource_TouchScreen); |
| io.AddMousePosEvent(touchLocation.x, touchLocation.y); |
| |
| BOOL hasActiveTouch = NO; |
| for (UITouch *touch in event.allTouches) |
| { |
| if (touch.phase != UITouchPhaseEnded && touch.phase != UITouchPhaseCancelled) |
| { |
| hasActiveTouch = YES; |
| break; |
| } |
| } |
| io.AddMouseButtonEvent(0, hasActiveTouch); |
| } |
| |
| -(void)touchesBegan:(NSSet<UITouch *> *)touches withEvent:(UIEvent *)event { [self updateIOWithTouchEvent:event]; } |
| -(void)touchesMoved:(NSSet<UITouch *> *)touches withEvent:(UIEvent *)event { [self updateIOWithTouchEvent:event]; } |
| -(void)touchesCancelled:(NSSet<UITouch *> *)touches withEvent:(UIEvent *)event { [self updateIOWithTouchEvent:event]; } |
| -(void)touchesEnded:(NSSet<UITouch *> *)touches withEvent:(UIEvent *)event { [self updateIOWithTouchEvent:event]; } |
| |
| #endif |
| |
| @end |
| |
| //----------------------------------------------------------------------------------- |
| // AppDelegate |
| //----------------------------------------------------------------------------------- |
| |
| #if TARGET_OS_OSX |
| |
| @interface AppDelegate : NSObject <NSApplicationDelegate> |
| @property (nonatomic, strong) NSWindow *window; |
| @end |
| |
| @implementation AppDelegate |
| |
| -(BOOL)applicationShouldTerminateAfterLastWindowClosed:(NSApplication *)sender |
| { |
| return YES; |
| } |
| |
| -(instancetype)init |
| { |
| if (self = [super init]) |
| { |
| NSViewController *rootViewController = [[AppViewController alloc] initWithNibName:nil bundle:nil]; |
| self.window = [[NSWindow alloc] initWithContentRect:NSZeroRect |
| styleMask:NSWindowStyleMaskTitled | NSWindowStyleMaskClosable | NSWindowStyleMaskResizable | NSWindowStyleMaskMiniaturizable |
| backing:NSBackingStoreBuffered |
| defer:NO]; |
| self.window.contentViewController = rootViewController; |
| [self.window center]; |
| [self.window makeKeyAndOrderFront:self]; |
| } |
| return self; |
| } |
| |
| @end |
| |
| #else |
| |
| @interface AppDelegate : UIResponder <UIApplicationDelegate> |
| @property (strong, nonatomic) UIWindow *window; |
| @end |
| |
| @implementation AppDelegate |
| |
| -(BOOL)application:(UIApplication *)application |
| didFinishLaunchingWithOptions:(NSDictionary<UIApplicationLaunchOptionsKey,id> *)launchOptions |
| { |
| UIViewController *rootViewController = [[AppViewController alloc] init]; |
| self.window = [[UIWindow alloc] initWithFrame:UIScreen.mainScreen.bounds]; |
| self.window.rootViewController = rootViewController; |
| [self.window makeKeyAndVisible]; |
| return YES; |
| } |
| |
| @end |
| |
| #endif |
| |
| //----------------------------------------------------------------------------------- |
| // Application main() function |
| //----------------------------------------------------------------------------------- |
| |
| #if TARGET_OS_OSX |
| |
| int main(int argc, const char * argv[]) |
| { |
| return NSApplicationMain(argc, argv); |
| } |
| |
| #else |
| |
| int main(int argc, char * argv[]) |
| { |
| @autoreleasepool |
| { |
| return UIApplicationMain(argc, argv, nil, NSStringFromClass([AppDelegate class])); |
| } |
| } |
| |
| #endif |