autoroll/BUILD.bazel

load("@rules_pkg//:pkg.bzl", "pkg_tar")
load("//bazel:skia_app_container.bzl", "skia_app_container")

skia_app_container(
    name = "autoroll_google3_container",
    dirs = {
        "/usr/local/bin": [
            [
                "//autoroll/go/autoroll-google3:autoroll-google3",
                "0755",
            ],
        ],
    },
    empty_dirs = {"/mnt/pd0/autoroll_workdir": "0777"},
    repository = "skia-public/autoroll-google3",
)

pkg_tar(
    name = "autoroll_be_cc_symlink",
    symlinks = {
        "/usr/bin/cc": "/usr/bin/gcc",
    },
)

skia_app_container(
    name = "autoroll_be_container",
    base_image = "@base-cipd",
    dirs = {
        "/usr/local/bin": [
            [
                "//autoroll/go/autoroll-be:autoroll-be",
                "0755",
            ],
            [
                "@bazelisk//file",
                "0755",
            ],
        ],
    },
    env = {
        "PATH": "/go/bin:${PATH}",
    },
    extra_tars = [
        "@autoroll-be-apt-install//:flat",
        "//bazel/go:go_toolchain_tar",
        ":autoroll_be_cc_symlink",
    ],
    repository = "skia-public/autoroll-be",
)

skia_app_container(
    name = "autoroll_fe_container",
    dirs = {
        "/usr/local/bin": [
            [
                "//autoroll/go/autoroll-fe:autoroll-fe",
                "0755",
            ],
        ],
        "/usr/local/share/autoroll-fe/dist/img": [
            [
                "//autoroll/images:%s" % favicon,
                "0644",
            ]
            for favicon in [
                "favicon-failure.svg",
                "favicon-stopped.svg",
                "favicon-success.svg",
                "favicon-unknown.svg",
            ]
        ],
        "/usr/local/share/autoroll-fe/dist": [
            [
                "//autoroll/pages:production/%s.%s" % (page, ext),
                "0644",
            ]
            for page in [
                "index",
                "config",
                "roller",
                "mode-history",
                "roll-history",
                "strategy-history",
            ]
            for ext in [
                "css",
                "html",
                "js",
            ]
        ],
    },
    repository = "skia-public/autoroll-fe",
)