fiddlek/BUILD.bazel

load("@rules_pkg//:pkg.bzl", "pkg_tar")
load("//bazel:skia_app_container.bzl", "skia_app_container")

skia_app_container(
    name = "fiddle_container",
    base_image = "//kube/basealpine:basealpine",
    dirs = {
        "/usr/local/bin": [
            [
                "//fiddlek/go/fiddle:fiddle",
                "0755",
            ],
        ],
        "/etc/fiddle/source": [
            [
                "//fiddlek/source:%s" % img,
                "0755",
            ]
            for img in [
                "1.png",
                "2.png",
                "3.png",
                "4.png",
                "5.png",
                "6.png",
            ]
        ],
        "/usr/local/share/fiddle/dist": [
            [
                "//fiddlek/pages:production/%s.%s" % (page, ext),
                "0644",
            ]
            for page in [
                "embed",
                "named",
                "newindex",
            ]
            for ext in [
                "css",
                "html",
                "js",
            ]
        ],
    },
    entrypoint = "/usr/local/bin/fiddle",
    repository = "skia-public/fiddle",
)

pkg_tar(
    name = "swiftshader_include_tar",
    srcs = ["@swiftshader//:all_files"],
    package_dir = "/usr/local",
    strip_prefix = "external/+git_repository+swiftshader",
)

pkg_tar(
    name = "swiftshader_libs_tar",
    srcs = [
        "@swiftshader_libegl//file",
        "@swiftshader_libglesv2//file",
    ],
    package_dir = "/usr/local/lib",
)

skia_app_container(
    name = "fiddler_container-base",
    base_image = "@debian-testing-slim",
    ca_certs = True,
    create_skia_user = True,
    dirs = {
        "/usr/local/bin": [
            [
                "//fiddlek/go/fiddler:fiddler",
                "0755",
            ],
            [
                "//fiddlek/go/fiddle_secwrap:fiddle_secwrap",
                "0755",
            ],
        ],
        # Note source is fiddle, not fiddler, to agree with the fiddle image.
        "/etc/fiddle/source": [
            [
                "//fiddlek/source:%s" % img,
                "0644",
            ]
            for img in [
                "1.png",
                "2.png",
                "3.png",
                "4.png",
                "5.png",
                "6.png",
            ]
        ],
    },
    entrypoint = "/usr/local/bin/fiddler",
    env = {
        "SSL_CERT_FILE": "/etc/ssl/certs/ca-certificates.crt",
    },
    extra_tars = [
        "@fiddler-base-apt-install//:flat",
        ":swiftshader_include_tar",
        ":swiftshader_libs_tar",
    ],
    repository = "skia-public/fiddler-base",
    visibility = ["//visibility:public"],
)